@PACKAGE_INIT@

# Variable to inspect installed schema versions.
set(IFCOPENSHELL_SCHEMA_VERSIONS @SCHEMA_VERSIONS@)

set(IFCOPENSHELL_WITH_OPENCASCADE @WITH_OPENCASCADE@)
set(IFCOPENSHELL_WITH_CGAL @WITH_CGAL@)
set(IFCOPENSHELL_IFCXML @IFCXML_SUPPORT@)
set(IFCOPENSHELL_WITH_ROCKSDB @WITH_ROCKSDB@)

include(CMakeFindDependencyMacro)

set(Boost_USE_STATIC_LIBS ON)
set(Boost_USE_STATIC_RUNTIME OFF)
set(Boost_USE_MULTITHREADED ON)
set(Boost_COMPONENTS system program_options regex thread date_time iostreams)
find_dependency(Boost CONFIG COMPONENTS ${Boost_COMPONENTS})
find_dependency(Eigen3 CONFIG)

if(IFCOPENSHELL_WITH_ROCKSDB)
    find_dependency(zstd CONFIG)
    find_dependency(RocksDB CONFIG)
endif()

if(IFCOPENSHELL_IFCXML)
    find_dependency(LibXml2 CONFIG)
endif()


if(IFCOPENSHELL_WITH_CGAL)
    find_dependency(CGAL CONFIG)
endif()

if(IFCOPENSHELL_WITH_OPENCASCADE)
    find_dependency(OpenCASCADE CONFIG)
    if(OpenCASCADE_VERSION VERSION_LESS "7.7.0")
        # cmake configs < 7.7.0 were not adding include directories to targets automatically.
        set_target_properties(TKernel PROPERTIES
            INTERFACE_INCLUDE_DIRECTORIES "${OpenCASCADE_INCLUDE_DIR}"
        )
    endif()
endif()

include("${CMAKE_CURRENT_LIST_DIR}/@CONFIG_TARGETS_FILENAME@")

check_required_components("@PROJECT_NAME@")